Hive Lateral View explode字段值为空时，导致数据异常丢失解决方案

1.问题描述

日常工作中，我们经常会用Lateral View 结合explode把非结构化数据转化成结构化数据，但是该方法对应explode的内容是有非null限制的，否则就有可能造成数据缺失。

SELECT name,info
FROM
  (
   SELECT name,
   	      split(info_list,',') as info_arrary
   FROM 
     (
      select '韩立' as name,'1,2,3' as info_list
      union all
      select '厉飞雨' as name,null as info_list
     ) t1     -- 构造测试数据
   ) t2
LATERAL VIEW explode(t2.info_arrary) a as info
;

查询结果：

查看结果我们可以发现‘厉飞雨’ 这条数据丢了，这会导致我们最终的统计数据出现错误。

2.查找原因

通过定位我们可以发现 ‘厉飞雨’ 这一行的info字段为null，其split之后的结果自然也是为null，通过LATERAL VIEW explode之后会形成一个为null的view，这样无法关联出数据，该数据就会丢失。

3.解决办法(建议使用方法二)
3.1 方法一

对子查询中的split结果强制使用coalesce()方法，将null替换成一个为[’’]的数组，直接这么写会误以为string字符串。我们可以使用split(’’,’’)构造出一个[’’]数组，改写后的语句如下：

SELECT name,info
FROM
  (
   SELECT name,
          coalesce(split(info_list,','),split('','')) as info_arrary
   FROM
     (
      select '韩立' as name,'1,2,3' as info_list
      union all
      select '厉飞雨' as name,null as info_list
     ) t1     -- 构造测试数据
   ) t2
LATERAL VIEW OUTER explode(t2.info_arrary) a as info
;

查询结果：

请注意 ‘厉飞雨’ 的结果为空字符，不是null。

3.2 方法二

使用官方提供的LATERAL VIEW OUTER来进行解决，该方法类似于left outer join，即如果explode出来的结果为null，也会保留记录，只不过对应字段为null，改写后的语句如下：

SELECT name,info
FROM
  (
   SELECT name,
          split(info_list,',') as info_arrary
   FROM 
     (
      select '韩立' as name,'1,2,3' as info_list
      union all
      select '厉飞雨' as name,null as info_list
     ) t1     -- 构造测试数据
   ) t2
LATERAL VIEW OUTER explode(t2.info_arrary) a as info
;

查询结果：

请注意 ‘厉飞雨’ 的结果为null，而不是空字符。

以下是官方文档LateralView( 官网链接)关于该用法的解释：

The user can specify the optional OUTER keyword to generate rows even when a LATERAL VIEW usually would not generate a row. This happens when the UDTF used does not generate any rows which happens easily with explode when the column to explode is empty. In this case the source row would never appear in the results. OUTER can be used to prevent that and rows will be generated with NULL values in the columns coming from the UDTF.

为了保持代码的稳定性与数据的准确性，建议使用第二种方法。