图元指的是cad中的基本图形，在dwg中有自己专有的一段数据描述，包括位置、形状、线性、颜色、图层等等。比如一个圆，关键是圆心座标，半径，知道这两个数据我们就能在cad中生成它。
生成图元有两种方法，其一，利用平时操作cad的按键所代表的命令描述。以圆为例，在命令行输入如下代码可以生成如下圆心位于原点，半径5的一个圆。
(vl-cmdf "circle" '(0 0) 5 );2014以下可以用command也一样，高版本用command-s也一样
其二，利用entmake方法直接生成图元组码。形如
(entmake (list'(0 . "CIRCLE") (cons10 '(0 0)) (cons40 5)))
也能达到方法一完成的效果。我更推荐用entmake方法，因为一这种方法不会应为鼠标或者捕捉等原因影响，二在批量生成图元时要比vl-cmdf方法快很多。我把自己总结以及网上收集的一些例子列出来。
;1、直线
(entmake (list '(0 . "LINE") (cons 10 pt1) (cons 11 pt2)))
;2、两顶点多段线(多顶点类似)
(entmake (list '(0 . "LWPOLYLINE") '(100 . "AcDbEntity") '(100 . "AcDbPolyline") (cons 90 2) (cons 10 pt1) (cons 10 pt2)))
;3、点表生成多段线
(entmake (append (list '(0 . "LWPOLYLINE") '(100 . "AcDbEntity") '(100 . "AcDbPolyline") (cons 90 (length lst)))
(mapcar '(lambda (pt)(cons 10 pt)) lst ))
)
;4、圆
(entmake (list '(0 . "CIRCLE") (cons 10 pt) (cons 40 r)))
;5、圆弧
(entmake (list '(0 . "ARC") (cons 10 pt) (cons 40 r) (cons 50 ang1) (cons 51 ang2)))
;6、单行文本
(entmake (list '(0 . "TEXT") (cons 1 str) (cons 10 pt) (cons 40 5)))
;7、多行文本
(entmake (list '(0 . "MTEXT") '(100 . "AcDbEntity") '(100 . "AcDbMText") '(7 . "Standard") (cons 1 str) (cons 10 pt)))
;8、半径标注
(entmake (list '(0 . "DIMENSION") '(100 . "AcDbEntity") '(100 . "AcDbDimension")(cons 10 pt) '(70 . 36) '(100 . "AcDbRadialDimension") (cons 15 pt1) ) )
;9、直径标注
(entmake (list '(0 . "DIMENSION") '(100 . "AcDbEntity") '(100 . "AcDbDimension") (cons 10 pt1) (cons 11 pt2) '(70 . 163) '
(100 . "AcDbDiametricDimension") (cons 15 pt3)
)
)
;10、水平标注
(entmake (list '(0 . "DIMENSION") '(100 . "AcDbEntity") '(100 . "AcDbDimension") (cons 10 pt) '(70 . 32) '(1 . "") '(100 . "AcDbAlignedDimension")
(cons 13 pt1) (cons 14 pt2) '(100 . "AcDbRotatedDimension")
)
)
;11、垂直标注
(entmake (list '(0 . "DIMENSION") '(100 . "AcDbEntity") '(100 . "AcDbDimension") (cons 10 pt) '(70 . 32) '(1 . "") '(100 . "AcDbAlignedDimension")
(cons 13 pt1) (cons 14 pt2) '(50 . 1.5708) '(100 . "AcDbRotatedDimension")
)
)
;12、倾斜标注
(entmake (list '(0 . "DIMENSION") '(100 . "AcDbEntity") '(100 . "AcDbDimension") (cons 10 pt1) '(70 . 33) '(1 . "") '(100 . "AcDbAlignedDimension")
(cons 13 pt2) (cons 14 pt3)
)
)
;13、entmake生成普通块
(defun emkblk (ss pt name / i)
(entmake (list '(0 . "block") (cons 2 name) '(70 . 0) (cons 10 pt)))
(repeat (setq i (sslength ss)) (entmake (cdr (entget (ssname ss (setq i (1- i)))))) )
(entmake '((0 . "ENDBLK")))
(command "_.erase" ss "")
(entmake (list '(0 . "INSERT") (cons 2 name) (cons 10 pt)))
)
;14、entmake插入普通块
(entmake (list '(0 . "INSERT") (cons 2 name) (cons 10 pt)))
;15 、entmake生成无名块
(defun emkunameblk (ss pt / i name)
(entmake (list '(0 . "block") '(2 . "*U") '(70 . 1) (cons 10 pt)))
(repeat (setq i (sslength ss)) (entmake (cdr (entget (ssname ss (setq i (1- i)))))) )
(setq name (entmake '((0 . "ENDBLK"))))
(command "_.erase" ss "")
(entmake (list '(0 . "INSERT") (cons 2 name) (cons 10 pt)))
name
)
;16、将选择集做成属性块(选择集中单行文本作为属性)
(defun emkattblk (ss pt name / ent i)
(entmake (list '(0 . "block") (cons 2 name) '(70 . 2) (cons 10 pt)))
(repeat (setq i (sslength ss))
(setq ent (entget (ssname ss (setq i (1- i)))))
(if (= (cdr (assoc 0 ent)) "TEXT")
(entmake (list '(0 . "ATTDEF") (assoc 10 ent) (assoc 40 ent) (assoc 1 ent) (cons 3 (cdr (assoc 1 ent)))
(cons 2 (cdr (assoc 1 ent))) '(70 . 0)))
(entmake (cdr ent))
)
)
(entmake '((0 . "ENDBLK")))
)
;17、生成图层
(entmake (list '(0 . "LAYER") '(100 . "AcDbSymbolTableRecord") '(100 . "AcDbLayerTableRecord") '(70 . 0) '(6 . "Continuous")
(cons 2 name)
)
)
;18、创建新线型
(entmake (list '(0 . "LTYPE") '(100 . "AcDbSymbolTableRecord") '(100 . "AcDbLinetypeTableRecord") (cons 2 "BERDIG 5-545") ' (3 . "Border ____ ____ ____ ____ ____") '(70 . 0) '(73 . 2) '(40 . 15.0) '(49 . 10.0) '(74 . 0) '
(49 . -5.0) '(74 . 0) ) )
;19、引线
(entmake (list '(0 . "LEADER") '(100 . "AcDbEntity") '(100 . "AcDbLeader") (cons 10 pt) (cons 10 pt1)
(cons 10 pt2)
)
)
;20、构造线
(entmake (list '(0 . "XLINE") '(100 . "AcDbEntity") '(100 . "AcDbXline") (cons 10 pt) (cons 11 pt1)))
;21、椭圆
(entmake '((0 . "ELLIPSE") (100 . "AcDbEntity")(100 . "AcDbEllipse")(10 3969.6 4289.14 0.0)(11 -1828.47 0.0 0.0)
(40 . 0.416093)
(42 . 6.28319)
)
)
;22、 点
(entmake (list '(0 . "POINT") (cons 10 pt)))
;23、entmake文字样式
(entmake (list '(0 . "STYLE") '(100 . "AcDbSymbolTableRecord") '(100 . "AcDbTextStyleTableRecord") (cons 2 name) '(70 . 0)
(cons 40 h) (cons 41 w) '(3 . "romans.shx") '(4 . "Hztxts.shx")
)
)
;24、 建立第一级标注样式(来源于论坛)
(entmake (list '(0 . "DIMSTYLE")
'(100 . "AcDbSymbolTableRecord")
'(100 . "AcDbDimStyleTableRecord")
'(70 . 0)
(cons 340 (tblobjname "style" "Standard")) ; 文字样式名
(cons 2 "普通螺纹") ; 标注样式名
'(3 . "M<>") ; 标注前缀
'(40 . 0.0) ; 标注特征比例，缩放到布局
'(41 . 2.5) ; 箭头尺寸
'(42 . 1.5) ; 起点偏移量
'(43 . 5.5) ; 基线间距
'(44 . 1.5) ; 超出尺寸线
'(47 . 0.000) ; 上偏差
'(48 . 0.000) ; 下偏差
'(71 . 0) ; 公差无
'(77 . 1) ; 文字在尺寸线上方
'(74 . 1) ;
'(140 . 3.0) ; 文字高度
'(141 . -2.5) ; 圆心标记
'(144 . 1.0) ; 测量比例单位
'(146 . 0.7) ; 公差高度比例
'(147 . 1.0) ; 文字从尺寸线偏移
'(172 . 2) ; 尺寸界线间连线
'(176 . 256) ; 随层
'(177 . 256) ; 随层
'(178 . 256) ; 随层
'(271 . 3) ; 尺寸标注精度
'(272 . 3) ; 公差标注精度
'(275 . 0) ; 角度标注制式，十进制。
'(288 . 1) ; 手动放置尺寸
)
)
;25、点表生成样条曲线(感谢院长提供)
(entmake (append
(list '(0 . "SPLINE") '(100 . "AcDbEntity") '(100 . "AcDbSpline") '(71 . 3))
(mapcar '(lambda (pt) (cons 11 pt)) ptlst)
)
)
;26、生成SOLID (pt1234四点围成图形，如三点则最后两点相同)
(entmake (list '(0 . "SOLID") (cons 10 pt1) (cons 11 pt2) (cons 12 pt4) (cons 13 pt3)))
;;27 [功能] X轴(Y轴)构造线
;;Flag T时,在X轴线上产生射线
;;示例 (EntmakeXline (getpoint) "X")产生平行X轴的射线
(defun EntmakeXline (pt Flag / P1)
(if Flag
(setq p1 '(1 0 0))
(setq p1 '(0 1 0))
)
(entmakeX (list '(0 . "XLINE")
'(100 . "AcDbEntity")
'(100 . "AcDbXline")
(cons 10 pt)
(cons 11 p1)
)
)
)
;;;
;;;*虚线,虚线 __ __ __ __ __ __ __ __ __
;;;A,4,-2
;;;*点画线,点画线 ___ . ___ . ___ . ___ . ___
;;;A,15,-1.5,0.5,-1.5
;;;*双点画线,双点画线 ___ .. ___ .. ___ .. ___
;;;A,15,-1.7,0.5,-1.7,0.5,-1.7
(entmake
(list '(0 . "LTYPE")
'(100 . "AcDbSymbolTableRecord")
'(100 . "AcDbLinetypeTableRecord")
(cons 2 "双点画线")
'(3 . "双点画线 ___ .. ___ .. ___ .. ___")
'(70 . 0)
'(73 . 6)
'(40 . 21.1)
'(49 . 15)
'(74 . 0)
'(49 . -1.7)
'(74 . 0)
'(49 . 0.5)
'(74 . 0)
'(49 . -1.7)
'(74 . 0)
'(49 . 0.5)
'(74 . 0)
'(49 . -1.7)
'(74 . 0)
)
)
(entmake
(list '(0 . "LTYPE")
'(100 . "AcDbSymbolTableRecord")
'(100 . "AcDbLinetypeTableRecord")
(cons 2 "点画线")
'(3 . "点画线 ___ . ___ . ___ . ___ . ___")
'(70 . 0)
'(73 . 4)
'(40 . 18.5)
'(49 . 15)
'(74 . 0)
'(49 . -1.5)
'(74 . 0)
'(49 . 0.5)
'(74 . 0)
'(49 . -1.5)
'(74 . 0)
)
)
(entmake
(list '(0 . "LTYPE")
'(100 . "AcDbSymbolTableRecord")
'(100 . "AcDbLinetypeTableRecord")
(cons 2 "虚线")
'(3 . "虚线 __ __ __ __ __ __ __ __ __")
'(70 . 0)
'(73 . 2)
'(40 . 6.0)
'(49 . 4.0)
'(74 . 0)
'(49 . -2.0)
'(74 . 0)
)
)
(defun 3DFace (p1 p2 p3 p4)
(entmakex (list (cons 0 "3DFACE")
(cons 10 p1)
(cons 11 p2)
(cons 12 p3)
(cons 13 p4))))
(defun Arc (cen rad sAng eAng)
(entmakex (list (cons 0 "ARC")
(cons 10 cen)
(cons 40 rad)
(cons 50 sAng)
(cons 51 eAng))))
(defun AttDef (tag prmpt def pt hgt flag)
(entmakex (list (cons 0 "ATTDEF")
(cons 10 pt)
(cons 40 hgt)
(cons 1 def)
(cons 3 prmpt)
(cons 2 tag)
(cons 70 flag))))
(defun Circle (cen rad)
(entmakex (list (cons 0 "CIRCLE")
(cons 10 cen)
(cons 40 rad))))
(defun Ellipse (cen maj ratio)
(entmakex (list (cons 0 "ELLIPSE")
(cons 100 "AcDbEntity")
(cons 100 "AcDbEllipse")
(cons 10 cen)
(cons 11 maj)
(cons 40 ratio)
(cons 41 0)
(cons 42 (* 2 pi)))))
(defun Insert (pt Nme)
(entmakex (list (cons 0 "INSERT")
(cons 2 Nme)
(cons 10 pt))))
(defun Line (p1 p2)
(entmakex (list (cons 0 "LINE")
(cons 10 p1)
(cons 11 p2))))
(defun LWPoly (lst cls)
(entmakex (append (list (cons 0 "LWPOLYLINE")
(cons 100 "AcDbEntity")
(cons 100 "AcDbPolyline")
(cons 90 (length lst))
(cons 70 cls))
(mapcar (function (lambda (p) (cons 10 p))) lst))))
(defun M-Text (pt str)
(entmakex (list (cons 0 "MTEXT")
(cons 100 "AcDbEntity")
(cons 100 "AcDbMText")
(cons 10 pt)
(cons 1 str))))
(defun Point (pt)
(entmakex (list (cons 0 "POINT")
(cons 10 pt))))
(defun Polyline (lst)
(entmakex (list (cons 0 "POLYLINE")
(cons 10 '(0 0 0))))
(mapcar
(function (lambda (p)
(entmake (list (cons 0 "VERTEX") (cons 10 p))))) lst)
(entmakex (list (cons 0 "SEQEND"))))
(defun Solid (p1 p2 p3 p4)
(entmakex (list (cons 0 "SOLID")
(cons 10 p1)
(cons 11 p2)
(cons 12 p3)
(cons 13 p4))))
(defun Text (pt hgt str)
(entmakex (list (cons 0 "TEXT")
(cons 10 pt)
(cons 40 hgt)
(cons 1 str))))
(defun Trce (p1 p2 p3 p4)
(entmakex (list (cons 0 "TRACE")
(cons 10 p1)
(cons 11 p2)
(cons 12 p3)
(cons 13 p4))))
(defun xLine (pt vec)
(entmakex (list (cons 0 "XLINE")
(cons 100 "AcDbEntity")
(cons 100 "AcDbXline")
(cons 10 pt)
(cons 11 vec))))
(defun Layer (Nme)
(entmake (list (cons 0 "LAYER")
(cons 100 "AcDbSymbolTableRecord")
(cons 100 "AcDbLayerTableRecord")
(cons 2 Nme)
(cons 70 0))))
(defun Layer (Nme Col Ltyp LWgt Plt)
(entmake (list (cons 0 "LAYER")
(cons 100 "AcDbSymbolTableRecord")
(cons 100 "AcDbLayerTableRecord")
(cons 2 Nme)
(cons 70 0)
(cons 62 Col)
(cons 6 Ltyp)
(cons 290 Plt)
(cons 370 LWgt))))
;功能：插入块(entmake法 属性或非属性块)
;(entmakeinsertb "ccd1" (getpoint))
;(entmakeinsertb "tybtl" (getpoint))
(defun entmakeinsertb (name pt / e en p10 str)
(defun mkattrib (pt str h)
(entmake (list
'(0 . "attrib")
'(100 . "acdbentity")
'(100 . "acdbtext")
(cons 10 pt)
(cons 40 h)
(cons 1 str)
'(100 . "acdbattribute")
(cons 2 str)
'(70 . 0)
)
)
)
(setq e (tblobjname "block" name))
(setq pt (trans pt 1 0))
(cond ((equal (assoc 70 (entget e)) '(70 . 0))
(entmake (list '(0 . "insert") (cons 2 name) (cons 10 pt)))
)
(T
(entmake (list '(0 . "insert") '(66 . 1) (cons 2 name) (cons 10 pt)))
(while (setq e (entnext e))
(setq en (entget e))
(cond ((equal (assoc 0 en) '(0 . "attdef"))
(setq p10 (mapcar '+ pt (cdr (assoc 10 en))))
(setq str (cdr (assoc 1 en)))
(mkattrib p10 str (cdr (assoc 40 en)))
)
)
)
(entmake '((0 . "seqend")))
)
)
(entlast)
)
;以下代码创建一个名为aaaa(300组码)，已命名(70组码)，可选(71组码)，包含三个选取对象(340组码)的group对象
(entmake (list (cons 0 "GROUP")
(cons 100 "AcDbGroup")
(cons 300 "aaaa")
(cons 70 0)
(cons 71 1)
(cons 340 (car (entsel)))
(cons 340 (car (entsel)))
(cons 340 (car (entsel)))
)
)
ENTMAKE一些实体LISP相关 2007-08-31 07:49:22 阅读88 评论0 字号：大中小
;;; ==================================================================
(defun txt-mktxt (string insertionpt hight width ang sty)
(if (= ang nil)
(setq ang 0)
)
(if (= width nil)
(setq width 1)
)
(if (= sty nil)
(setq sty (getvar "TEXTSTYLE"))
)
(if (setq ent (entmakex (list '(0 . "TEXT") '(100 . "AcDbEntity") '
(100 . "AcDbText") (cons 1 string)
(cons 10 insertionpt) (cons 40 hight)
(cons 41 width) (cons 50 (deg2rad ang))
(cons 7 sty)
)
)
)
ent
)
)
;;; ==================================================================
(defun txt-mkmtxt (string insertionpt ang hight sty)
(if (= hight nil)
(setq hight (getvar "TEXTSIZE"))
)
(if (= sty nil)
(setq sty (getvar "TEXTSTYLE"))
)
(if (setq ent (entmakex (list '(0 . "MTEXT") '(100 . "AcDbEntity") '
(100 . "AcDbMText") (cons 10 insertionpt)
(cons 40 hight) '(41 . 100.0) '(71 . 1) '
(72 . 5) (cons 1 string) (cons 7 sty) '
(11 1.0 0.0 0.0) (cons 42 (* 0.8 higth))
(cons 43 higth) (cons 50 ang)
)
)
)
ent
)
)
;;; ==================================================================
(defun txt-mkline (p1 p2)
(if (setq ent (entmakex (list '(0 . "LINE") '(100 . "AcDbEntity") '
(100 . "AcDbLine") (cons 10 p1)
(cons 11 p2) '(210 0. 0. 1.)
)
)
)
ent
)
)
;;; ==================================================================
(defun txt-mkcircle (p r / ent)
(if (setq ent (entmakex (list '(0 . "CIRCLE") '(100 . "AcDbEntity") '
(100 . "ACDbCircle") (cons 10 p)
(cons 40 r) '(210 0. 0. 1.)
)
)
)
ent
)
)
;;; ==================================================================
(defun txt-mkarc (p r ang1 ang2 / ent)
(if (setq ent (entmakex (list '(0 . "arc") '(100 . "AcDbEntity") '
(100 . "ACDbCircle") (cons 10 p)
(cons 40 r) '(210 0. 0. 1.) '(100 .
"AcDbArc"
)
(cons 50 ang1) (cons 51 ang2)
)
)
)
ent
)
)
;;; ==================================================================
(defun txt-mkellipse (cen endp ratio / ent)
(if (setq ent (entmakex (list '(0 . "ELLIPSE") '(100 . "AcDbEntity") '
(100 . "AcDbEllipse") (cons 10 cen)
(cons 11 endp) (cons 40 ratio) '(41 . 0)
(cons 42 (* 2 pi)) '(210 0 0 1)
)
)
)
ent
)
)
;;; ==================================================================
(defun txt-mkelarc (cen endp ratio ang1 ang2 / ent)
(if (setq ent (entmakex (list '(0 . "ELLIPSE") '(100 . "AcDbEntity") '
(100 . "AcDbEllipse") (cons 10 cen)
(cons 11 endp) (cons 40 ratio)
(cons 41 ang1) (cons 42 ang2) '(210 0 0 1)
)
)
)
ent
)
)
;;; ==================================================================
;;; 已知圆和其上两点，建弧
(defun txt-mkarc-byc (ename pt1 pt2 / ang1 ang2 cen ent entlst)
(setq entlst (entget ename)
entlst (vl-remove (assoc -1 entlst) entlst)
entlst (vl-remove (assoc 330 entlst) entlst)
entlst (vl-remove (assoc 5 entlst) entlst)
entlst (vl-remove (assoc 0 entlst) entlst)
entlst (vl-remove (assoc 50 entlst) entlst)
entlst (vl-remove (assoc 51 entlst) entlst)
cen (txt-get-dxf 10 ename)
ang1 (angle cen pt1)
ang2 (angle cen pt2)
entlst (append
(list (cons 0 "arc") (cons 100 "AcDbArc"))
entlst
(list (cons 50 ang1) (cons 51 ang2))
)
)
(if (setq ent (entmakex entlst))
ent
)
)
;;; ==================================================================
;;; 已知椭圆和其上两点，建弧
(defun txt-mkelarc-bye (ename pt1 pt2 / ang1 ang2 cen endp ent entlst ratio)
(setq entlst (entget ename)
entlst (vl-remove (assoc -1 entlst) entlst)
entlst (vl-remove (assoc 330 entlst) entlst)
entlst (vl-remove (assoc 5 entlst) entlst)
entlst (vl-remove (assoc 0 entlst) entlst)
entlst (vl-remove (assoc 41 entlst) entlst)
entlst (vl-remove (assoc 42 entlst) entlst)
cen (txt-get-dxf 10 ename)
endp (txt-get-dxf 11 ename)
ratio (txt-get-dxf 40 ename)
ang1 (txt-pt2ell-param pt1 cen endp ratio)
ang2 (txt-pt2ell-param pt2 cen endp ratio)
entlst (append
(list (cons 0 "ELLIPSE"))
entlst
(list (cons 41 ang1) (cons 42 ang2))
)
)
(if (setq ent (entmakex entlst))
ent
)
)
;;; ==================================================================
(defun Entmake-Spline (ptn / a)
(entmake (append (list '(0 . "SPLINE")
'(100 . "AcDbEntity")
'(100 . "AcDbSpline")
'(71 . 3)
)
(mapcar '(lambda (pt) (cons 11 pt)) ptn)
)
)
(entlast)
)
;; el 实体dxf 表
;; tylst 新的值
;; (xd-modent el '((8 . "1") (62 . 1)))
(defun xd-modent (el tylst / c)
(foreach n tylst
(if (setq c (assoc (car n) el))
(setq el (subst n c el))
(setq el (append el (list n)))
)
)
(entmod el)
)
;;[功能]点表创建实心填充
;;[用法]用法(LC:entmake-HTCH PTlst Layname)
;;[用法]用法(LC:entmake-HTCH (LC-lst-delsame1 (LC-WH-vxs (car (entsel"\n 请选择要填充的范围线："))) 0.001)(getstring "\n 请输入填充后图层名："))
;;[作者]BY 老仓测绘上班记
(defun LC:entmake-HTCH (PTLST LAYNAME / LST)
(setq lst (append(list
'(0 . "HATCH")
'(100 . "AcDbEntity")
'(67 . 0)
'(410 . "Model")
(cons 8 Layname)
'(100 . "AcDbHatch")
'(10 0.0 0.0 0.0)
'(210 0.0 0.0 1.0)
'(2 . "SOLID");实心填充
'(70 . 1)
'(71 . 0)
'(91 . 1)
'(92 . 3)
'(72 . 0)
'(73 . 1)
(cons 93 (length ptlst))
)
(mapcar '(lambda(x)(cons 10 x)) ptlst)
(list'(97 . 0)
'(75 . 0)
'(76 . 1)
'(98 . 0))
)
)
(entmake lst)
)
(defun make-arc(p1 p2 p3 / cn lm:clockwise-p lst m1 m2)
;; Clockwise-p - Lee Mac
;; Returns T if p1,p2,p3 are clockwise oriented
(defun LM:Clockwise-p ( p1 p2 p3 )
(< (* (- (car p2) (car p1)) (- (cadr p3) (cadr p1)))
(* (- (cadr p2) (cadr p1)) (- (car p3) (car p1)))
)
)
(setq
p1(trans p1 1 0)
p2(trans p2 1 0)
p3(trans p3 1 0)
m1 (mid p1 p2)
m2 (mid p2 p3)
)
(if(setq cn
(inters
m1 (polar m1 (+ (angle p1 p2) (/ pi 2.)) 1.0)
m2 (polar m2 (+ (angle p2 p3) (/ pi 2.)) 1.0)
nil
)
)
(progn
(setq lst(append (list cn)
(if (LM:Clockwise-p p1 p2 p3)
(list (angle cn p3) (angle cn p1))
(list (angle cn p1) (angle cn p3))
)
(list (distance cn p1))
)
)
(entmake (append '((0 . "ARC")) (mapcar 'cons '(10 50 51 40) lst)))
)
)
)
以上所述只是生成一些图元的最少条件，如果你想调整颜色，线宽等等图元的特征，可以参考这些书中列出的图元组码(《dxflib-reference-manual》、《dxf参考手册》、《AutoCAD 群码表》)
接下来说，删除图元的方法。只要知道需要删除的图元名
(entdel name)或者(vla-delete objname)
聪明的读者，修改图元的方法就藏在生成图元的方法里面。
(entmod dxf)